From comp.graphics.raytracing Thu Aug 11 12:59:11 1994
Path: uniol!zib-berlin.de!zrz.TU-Berlin.DE!netmbx.de!Germany.EU.net!EU.net!uunet!cs.utexas.edu!not-for-mail
From: mkruse@saunix.sau.edu (Matt Kruse)
Newsgroups: comp.graphics.raytracing
Subject: The *Perfect* Sunset
Date: 6 Aug 1994 14:11:21 -0500
Organization: UTexas Mail-to-News Gateway
Lines: 81
Sender: nobody@cs.utexas.edu
Message-ID: <Pine.3.89.9408061455.A9901-0100000@saunix.sau.edu>
NNTP-Posting-Host: news.cs.utexas.edu

I've just spent a few hours creating what I think is an excellent sunset, 
if i do say so myself.  I started by looking at and taking snipits from 
sunset1.pov and clouds.pov - I don't remember the authors' names on 
those, but they are both very good.

I'd like to see other sunsets if anyone has them, so please post them 
here or e-mail them to me.  In fact, I'd like to see more tidbits of 
scene files posted here to look through.  It would be nice if someone 
found a great texture or built a good model of a common object and posted 
the code here.

Here's my sunset file - hope you like it.
(And you can use it in your own scenes if you want to, but you'll have to 
play with it a little to fit your scaling, etc.)


//SCENE: A nice sunset over an ocean (of course :)
//RENDER TIME:  Only takes about 15 minutes on a 486 dx-33 at 640x480
//              and a.5
//BY: Matt Kruse

#include "colors.inc"

camera { location <0, 1, -5> look_at <0, 1, 0> }

//WATER
plane { y, 0.0
   normal { waves 0.06 frequency 5000.0 scale 1000 }
   finish { reflection .1 phong 0.8 ambient .2 }
   pigment { color SkyBlue}
}

//FLOOR BENEATH WATER
plane { y, -1.0
   pigment { color SkyBlue }  
   finish { ambient 1.0  diffuse 0.0  crand 0.05 }
}

//CLOUDS
sphere{ <0, 0, 0>, 1 no_shadow
   texture { 
      pigment{bozo turbulence 1.0 octaves 3 lambda 6 
         color_map{ 
         [0.0 0.6 color Clear color Clear]  [0.94 color Gray70 filter .1] 
         [0.97 color Gray60 filter .075  ]  [1.0 color Gray70 filter .05] }
         }
      finish { ambient .7 diffuse 0 } scale 1/15
   }
   scale <3000, 100, 500>
}

//SKY
plane { z, 0
   pigment { onion
      color_map {
         [0.0 color red 1.0 green 0.3]
         [0.7 color Blue] } 
      scale <1000,600,600> }
   finish { ambient 0.25 diffuse 0.7 crand 0.05 }
translate z*600
}


//SUN
light_source {
   <0, 0, 0> color red 1 green.3
   looks_like {
      sphere { <0, 0, 0>, 50
         texture {
             pigment { gradient y 
                color_map{[0.0 color red 1.0 green 0.45 filter 0.35] 
                          [1.0 color red 1.0 green 0.60 filter 0.35] } 
                scale 100 }
             finish { ambient 1.0 diffuse 0.0 }
             normal {bumps .2}
         }
      }
   }
   translate z*550
}