From comp.graphics.raytracing Sun Oct  9 19:17:45 1994
Path: uniol!zib-berlin.de!fauern!xlink.net!howland.reston.ans.net!pipex!sunic!news.funet.fi!nntp.hut.fi!vipunen.hut.fi!kkivisal
From: kkivisal@vipunen.hut.fi (Kari Juhani Kivisalo)
Newsgroups: comp.graphics.raytracing
Subject: Re: Looking for author of sunrise1.gif
Date: 8 Oct 1994 19:10:19 GMT
Organization: Helsinki University of Technology
Lines: 93
Distribution: inet
Message-ID: <376qqr$3a3@nntp.hut.fi>
References: <Pine.SUN.3.90.941007092007.7684A-100000@pippin>
Reply-To: kkivisal@vipunen.hut.fi (Kari Juhani Kivisalo)
NNTP-Posting-Host: vipunen.hut.fi

In article <Pine.SUN.3.90.941007092007.7684A-100000@pippin> Jason Pratt <pratt@ncssm-server.ncssm.edu> writes:
>
>Hello all,
>
>	As the subject says, I'm looking for the author of sunrise1.gif, 
>which is in the Hall-Of-Fame at uniwa (and now ftp.povray.org).  

I posted a while ago very similar image as sunset.jpg to
a.b.p.m. I'm not the original author though, I just modified
some textures. The original scene was much darker.

The original author will probably recognize the scene file.

------------------------------------------------------------------------------
#include "colors.inc"

camera { location <0, 1, -5> look_at <0.1, 1.8, 0> }

plane { y, -0.01 no_shadow
   pigment { color green 0.4 blue 1}
   normal { waves 0.06 frequency 5000.0 scale 1000 }
   finish {  reflection 0.3 phong 0.8 ambient .25 refraction 0.8}

}


#declare f=0.9

//CLOUDS
sphere{ <0, 0, 0>, 1 no_shadow
   texture { 
      pigment{bozo turbulence 1.0 octaves 3 lambda 6 
         color_map{ 
         [0.0 0.6 color Clear color Clear]  [0.94 color Gray70 filter .1] 
         [0.97 color Gray60 filter .075  ]  [1.0 color Gray70 filter .05] }
         }
      finish { ambient 2/f diffuse 0 } scale 1/15
   }
   scale <3000, 100, 500>
}

#declare bg1=0.3
#declare bg2=0.7
#declare r1=1
#declare g1=0.6
#declare b2=1
#declare r3=(r1-bg2)/2+bg2
#declare g3=(g1-bg2)/2+bg2
#declare b3=(bg1-b2)/2+b2

// This is the coloured filter for sky.
sphere{ <0, 0, 0>, 1
   texture{
     pigment{
       gradient y
       turbulence 0.3
       color_map{
         [0   color rgbf<r1,g1,bg1,f>]
         [0.7 color rgbf<r3,g3,b3,f*0.8>]
         [1   color rgbf<bg2,bg2,b2,f*0.2>]
       }
     }
     finish{ambient 0 diffuse 0}
   }
scale<2990,95,490>
}

//SKY
plane { z, 600
   pigment { gradient y
      color_map {
         [0.0 color White]
         [1 color blue 2.5] } 
      scale <1,600,1> }
   finish { ambient 0.5/f diffuse 1/f}
}


//SUN
light_source {
   <0, 0, 0> color White
   looks_like {
      sphere { <0, 0, 0>, 50
         texture {
             pigment { color rgb<1.2,1.2,1.2>} 
             finish { ambient 1/f diffuse 0.0 }
         }
      }
   }
   translate z*550
}

K.K.