From comp.graphics.raytracing Tue Apr 12 20:20:39 1994
Newsgroups: comp.graphics.raytracing
Path: uniol!zib-berlin.de!news.th-darmstadt.de!terra.wiwi.uni-frankfurt.de!zeus.rbi.informatik.uni-frankfurt.de!news.dfn.de!scsing.switch.ch!swidir.switch.ch!univ-lyon1.fr!jussieu.fr!math.ohio-state.edu!howland.reston.ans.net!pipex!sunic!trane.uninett.no!eunet.no!EU.net!news.funet.fi!ousrvr.oulu.fi!ousrvr.oulu.fi!jkantola
From: jkantola@paju.oulu.fi (Jussi Kantola)
Subject: another good cloudy sky -texture
Message-ID: <JKANTOLA.94Apr8142255@paju.oulu.fi>
Sender: news@ousrvr.oulu.fi
Organization: The University of Oulu
Date: Fri, 8 Apr 1994 11:22:54 GMT
Lines: 100


//
// Every now and then I've tried to create a realistic cloud texture.
// I finally feel like I've succeeded :-).
// 
// Jussi Kantola (jkantola@paju.oulu.fi)
//

#include "colors.inc"
#include "textures.inc"

#declare Sky_Top = 100  // The distance from ground to the top of the sky

// A few different color_maps for the clouds, all of these are ok.

#declare Colors1 = color_map
   {
   [0.0 0.1 color rgb <2/3, 2/3, 1> color rgb <2/3, 2/3, 1>]
   [1.0 color White]
   }

#declare Colors2 = color_map  // Realistic
   {
   [0.0 0.1 color SkyBlue color SkyBlue]
   [1.0 color White]
   }

#declare Colors3 = color_map  // Very realistic!
   {
   [0.0 0.1 color SkyBlue color SkyBlue]
   [0.70 color rgb <4/5, 4/5, 5/6>]
   [1.0 color White]
   }

#declare Storm = color_map  // looks quite heavy with SkyColor in the lower layer!
   {
   [0.0 0.1 color Clear color Clear]
   [0.70 color rgbf <4/5, 4/5, 5/6, 1/2>]
   [1.0 color White]
   }

#declare Clouds = texture  // this is the cloud texture
   {
   pigment
      {
      bozo
      turbulence 0.5
      octaves 3   // doesn't have much effect
      lambda 6    // bigger values are worth trying
      color_map { Colors3 }
      }
   finish { ambient 1 diffuse 0 }
   scale 1/6   // please notice
   }
  
camera
   {
   location <0, 1, -5>
   right 4/3*x
   direction z
   up y
   look_at <0, 1, 0>
   }

light_source { <3, 8, -2> color rgb <1, 1, 1> }
light_source { <1, 4, -6> color rgb <1, 1, 1> }

plane    // a ground plane
   {
   y, 0
   pigment
      {
      hexagon
         color rgb <1, 1, 1>
         color rgb <2/3, 1/3, 1/3>
         color rgb <1/3, 0, 0>
      }
   finish { ambient 0.05 diffuse 0.95 brilliance 3 }
   }

sphere  // something to stare at, a bumpy mirror sphere
   {
   <0, 1, 0>, 1
   pigment { color White }
   normal { bumps 3/4 scale 1/10 }
   finish { Mirror }
   }

sphere  // the sky globe -- please notice the scalings!
   {
   <0, 0, 0>, 1
//   texture { pigment { color SkyBlue } }
   texture { Clouds }
   scale <Sky_Top*10, Sky_Top, Sky_Top*10>
   }

--
-- 
email: jkantola@paju.oulu.fi (Jussi Kantola)   IRC: jute
Nobody passes the test of time